Guia do Sensor de Humidade do Solo e Sensor de Chuva

Introdução

Algumas pessoas têm interesse em ter um pequeno jardim em casa ou alguns vasos no apartamento. Mas nesta vida agitada, nem sempre isso é possível. Se não cuidar das plantas adequadamente, o mais certo é que elas não sobrevivam.

Cada planta tem uma necessidade diferenciada de condição de habitat. Algumas precisam de humidade, outras precisam de mais sol. Outras nem precisam ser molhadas com tanta frequência, como o Cacto. E sobre irrigação, algumas precisam ter as folhagens molhadas, outras só podem ser irrigadas no solo.

O primeiro passo para ter plantas em casa é estudar sobre elas. Aprender como cuidar delas. Com a tecnologia atual, muita automação no cultivo das plantas poderá ser feita. Apesar de que muitas pessoas gostam de ter o contacto com as plantas, para um momento de relaxamento e reflexão.

Mas imagine se tiver que fazer uma viagem de férias de duas semanas? Quem cuidará das suas plantas? Várias pessoas já perderam as suas plantas, pois ficaram muito tempo sem ser irrigadas. Aí poderá usar a automação!

Neste tutorial, pretendemos introduzir a automação para irrigação de plantas com Arduino. Esta automação poderá ser usada para pequenos jardins ou então numa plantação maior, desde que tenha mais sistemas de controle que não permitam falhas.

Sensor de humidade do solo

O sensor de humidade do solo mede basicamente a resistividade da terra. Se a terra estiver molhada, menor será a resistividade. E se a terra estiver seca, a resistividade será maior. O dispositivo que deverá ser enterrado no solo, consiste de duas superfícies metalizadas e isoladas uma da outra. A terra molhada sobre estas superfícies, permitirá a passagem de corrente. Esta corrente ao passar pela resistência do solo desenvolverá uma diferença de potencial (tensão), que será medida pelo conversor ADC do Arduino (portas analógicas).

Quanto maior a tensão medida pelo Arduino, menor será a humidade do solo. No caso do solo húmido, a tensão deverá ser mais baixa.

A conexão entre o sensor YL-69 e o módulo comparador deverá ser feita com fios. Não existe polaridade nesses fios. Recomendamos a soldagem desses fios e o isolamento com tubos retrateis (quando aquecidos). Como ficarão sujeitos à humidade e água, as conexões precisam de ficar protegidas e isoladas. Um pouco de cola quente pode ser útil também para proteger as partes sujeitas à corrosão (conexões).

O módulo comparador deverá ficar distante das plantas e protegido contra água e humidade.

Sensor de humidade do solo

O módulo comparador tem um potenciómetro que serve para o ajuste da sensibilidade do sensor. Tem uma saída analógica (A0) e uma saída digital (D0). A saída analógica será usada para a medição da tensão no sensor de humidade. Existe uma resistência de 10K ohms que conecta um dos pinos do sensor aos 5V. O outro pino do sensor está conectado ao terra (GND).

Já a saída digital corresponde a uma comparação de um determinado valor de tensão, feita por um amplificador operacional e ajustada pelo potenciómetro. Através de alguns testes, deverá conseguir determinar um valor de tensão (limite de humidade). Se variar para um valor menor do que o determinado, a saída digital (D0) mudará de estado de HIGH para LOW e o LED D0 verde acenderá. Normalmente os potenciómetros já vêm ajustados para a metade da tensão de alimentação do sensor.

O pino GND do módulo deverá ser conectado no terra do Arduino. E o pino VCC deverá ser conectado aos 5V, também do Arduino. Ao ligar o módulo, o led D1 verde irá acender.

OBS: alguns módulos amplificadores tem pinagem diferente. Faça as conexões de acordo com as instruções.

O diagrama abaixo é do circuito do módulo comparador.

Sensor de chuva

O sensor de chuva tem o mesmo princípio de funcionamento do Sensor da humidade do solo. A diferença está na maior quantidade de linhas de deteção das gotas de chuva. Quando as gotas caem sobre a superfície do Sensor MH-RD, a resistividade do circuito diminui, portanto a tensão também. Quando a tensão estiver alta – sem chuva, tensão baixa – chuva!

O mesmo módulo comparador poderá ser usado para o Sensor de chuva, mas como montaremos os dois sensores no mesmo Arduino, será necessário um módulo comparador para cada sensor.

Recomendamos também a soldagem dos fios de conexão do sensor e o isolamento com tubos retrateis (quando aquecidos). Como ficarão sujeitos à humidade e água, as conexões precisam ficar protegidas e isoladas.

Montagem dos Sensores com Arduino

Esta é a montagem do Sensor de humidade do solo e do Sensor de chuva com o Arduino. Acrescentámos um módulo de relé para acionamento de uma pequena bomba d’água para irrigação das plantas. Use o contacto normalmente aberto do relé para controlar o circuito da bomba d’água.

O Sensor de humidade do solo deverá ser enterrado na terra do vaso ou do jardim. O sensor de chuva poderá ficar num local próximo, mas deverá ficar inclinado num ângulo de 45 graus aproximadamente. Para que as gotas possam escorrer e secar, depois que a chuva parar. Os fios das conexões dos sensores deverão ser protegidos contra a água e humidade, como já havíamos informado.

Como nesta montagem não usaremos as portas digitais, não será necessário ajustar os potenciómetros. O ajuste da deteção de humidade e da deteção de chuva deverá ser feito através da configuração de parâmetros no Sketch (programa). Através da tentativa-erro poderá fazer um ajuste mais preciso, mas as configurações já estão definidas para a metade da tensão de alimentação dos sensores.

O programa abaixo, monitora o Sensor de humidade do solo e o sensor de chuva a cada 5 segundos. Se o solo estiver seco e não estiver a chover, o Arduino acionará o relé da bomba para a irrigação. Começa um contador de tempo e a cada seis horas se ambos os sensores estiverem secos, a bomba d’água será novamente acionada.

A duração de tempo de acionamento da bomba d’água , deverá ser determinada através de testes. O tempo vai depender da quantidade de água que for bombeada para a planta. Recomendamos o uso de uma pequena bomba d’água (talvez uma bomba de aquário).

//Arduino - Sensor de humidade do solo e Sensor de chuva

int sensorHumidadeSolo = A0;   // Sensor de humidade pino A0 conectado no A0 do Arduino
int sensorChuva = A1;          // Sensor de chuva pino A0 conectado no A1 do Arduino
int portaRele = 4;             // porta de controlo do relé conectada no D4 do Arduino
int valorLimiteHumidade = 500; // valor da tensão de comparação (valor máximo = 1024)
int valorLimiteChuva = 500;    // valor da tensão de comparação (valor máximo = 1024)
bool chuva;                    // condição de chuva 
bool soloHumido;               // condição de solo Húmido 

void setup() {
 pinMode(sensorHumidadeSolo, INPUT); // Sensor de humidade - porta A0 é entrada
 pinMode(sensorChuva, INPUT);        // Sensor de chuva - porta A1 é entrada
 pinMode(portaRele, OUTPUT);         // Porta de controlo do Relé - D4 é saída
 digitalWrite(portaRele, HIGH);      // Mantém o relé desligado 
 Serial.begin(9600);                 // Inicia o Monitor Serial - 9600 Bps
}

void SensorDeChuva () {
 int valorSensorChuva = analogRead(sensorChuva); // faz a leitura do Sensor de chuva
 Serial.print(" Sensor de chuva = ");            // imprime mensagem
 Serial.print(valorSensorChuva);                 // imprime o valor do sensor
 if (valorSensorChuva < valorLimiteChuva) {      // se o valor < limite
   Serial.println("  => Está a chover");         // imprime mensagem
   chuva = 1 ;                                   // está a chover
 } else {                                        // senão
   Serial.println("  => Não está a chover");     // imprime mensagem
   chuva = 0 ;                                   // não está a chover 
 }
}

void SensorDeHumidade () {
 int valorSensorHumidadeSolo = analogRead(sensorHumidadeSolo); // faz a leitura do Sensor
 Serial.print(" Sensor de humidade do solo = ");               // imprime mensagem
 Serial.print(valorSensorHumidadeSolo);                        // imprime o valor do sensor
 if (valorSensorHumidadeSolo < valorLimiteHumidade) {          // se valor < limite
   Serial.println("  => O solo está húmido");                  // imprime mensagem
   soloHumido = 1 ;                                            // o solo está húmido 
 } else {                                                      // senão
   Serial.println("  => O solo está seco");                    // imprime mensagem
   soloHumido = 0 ;                                            // o solo está seco 
 }
}

void ControloDoRele() {             // ajuste o tempo de acionamento da bomba
 digitalWrite(portaRele, HIGH);     // relé desligado
 digitalWrite(portaRele, LOW);      // relé ligado
 Serial.println(" Relé acionado "); // imprime mensagem
 delay (1000);                      // tempo de acionamento da bomba d'água = 1 segundo
 digitalWrite(portaRele, HIGH);     // relé desligado
}

void loop() {
 for (int i = 1; i < 4321; i++) { // contagem de 1 a 4320 ( 4320 x 5 segundos = 6 horas)
   SensorDeChuva();               // faz a medição do sensor de chuva
   SensorDeHumidade();            // faz a medição do sensor de humidade do solo 
   if (chuva == 0 && soloHumido == 0 && i == 1) ControloDoRele();
   // o if aciona a bomba d'água a cada 6 horas se o tempo e o solo estiverem secos
   Serial.print(i*5);                             // imprime tempo em segundos 
   Serial.println(" segundos"); Serial.println(); // imprime mensagem e uma linha
   delay(5000);                                   // atraso de 5 segundos
 }
}

Sugestões interessantes

Se quiser implementar um controlo melhor das condições climáticas do seu jardim, sugerimos que acrescente também a monitorização da humidade e temperatura do ar . Veja este tutorial:

Guia básico dos Sensores de humidade e temperatura DHT11 e DHT22

Para programar o horário de irrigação das plantas, poderá acrescentar um relógio RTC. Imagine irrigar somente na parte da manhã ou da noite, quando o clima é mais ameno!

RTC – Real Time Clock DS1302, 1307 e 3231

Se quiser sofisticar ainda mais, uma outra sugestão é criar um sistema de monitorização de todas as condições do jardim através do acesso remoto na WEB. Mas isso fica para outro tutorial.